home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Gold Collection
/
Software Vault - The Gold Collection (American Databankers) (1993).ISO
/
cdr22
/
axsmycfg.zip
/
MYC.BAT
< prev
next >
Wrap
DOS Batch File
|
1993-05-01
|
12KB
|
371 lines
@echo off
cls
C:
if not exist C:\myc\nul MD C:\myc
CD\myc
rem dir C:\myc /W /A-D
rem *---------------------------------------------------------------------*
rem * Multiple configurations *
REM * (to add other configurations, edit the extra1,2,or 3 options AND.. *
REM * write the appropriate config.sys and autoexec.bat substitute files. *
rem *---------------------------------------------------------------------*
if "%1"=="?" goto help
if "%1"=="/?" goto help
if "%1"=="" goto pickcf
if "%1"=="d" goto dirmyc
if "%1"=="D" goto dirmyc
if "%1"=="A" goto allmsoft
if "%1"=="a" goto allmsoft
if "%1"=="B" goto best
if "%1"=="b" goto best
if "%1"=="p" goto pickcf
if "%1"=="P" goto pickcf
if "%1"=="m" goto mini
if "%1"=="M" goto mini
if "%1"=="r" goto ramdrive
if "%1"=="R" goto ramdrive
if "%1"=="L" goto lastcfg
if "%1"=="l" goto lastcfg
if "%1"=="U" goto Utility
if "%1"=="u" goto Utility
rem --------------------------edit extra1,2,3 below to add more options---
if "%1"=="e" goto extra1
if "%1"=="E" goto EXTRA1
if "%1"=="e" goto extra2
if "%1"=="E" goto EXTRA2
if "%1"=="e" goto extra3
if "%1"=="E" goto EXTRA3
:help
cls
echo.
echo *---------------------------------------------------------------------*
echo ! HELP & INFORMATION Myc.Bat reconfigures system by copying files !
echo ! ABOUT MYC.BAT to make alternate AUTOEXEC.BAT and CONFIG.SYS !
echo *---------------------------------------------------------------------*
echo.
rem --if Extra1,2,3 options used, add to appropriate new names below------
echo Parameters --Effect
echo ----------------------------------------------------
echo /? or ? --Help
echo D --Directory listing of MYC dir
echo C --C Language optimum programming Config.
echo P --Pick (Menu) P same as no parameter
echo A --All microsoft DOS--No other utiilities
echo B --Best (Memory optimized,Dos High, Etc)
echo L --last configuration (switch between 2 options)
echo R --Ramdrive added
echo M --Minimum, no TSRS, No HiMem etc.
echo U --Utility Menu--MYC copy, etc.
echo ----------------------------------------------------
echo (NOTE: Menu options and Parameters parallel each other)
echo.
echo SYNTAX----- MYC PARAMETER Example--- myc ?
echo.
choice /C:XP Enter X to Exit.. or P for Pick-Menu
if errorlevel 2 goto pickcf
goto endgate
:pickcf
rem -----if extra1,2,or3 amended, add letters to option menu below and add---
rem --- and\or correct the choice command line and errorlevel commands below---
echo.
echo PICK CONFIGURATION OPTIONS
echo *-----------------------------*
echo * H Help *
echo * D Directory of MYC *
echo * A AllMicroSoft *
echo * B Best *
echo * C C-Language Programming *
echo * R Ramdrive added *
echo * L Last configuration *
echo * M Minimum-No TSRS etc *
echo * U Utility-MYC edit etc. *
echo * X Exit--no changes *
echo *-----------------------------*
echo E(X)it in 10 seconds or...
choice /C:HBRLMCDAUX /T:X,10 ...SELECT:
if errorlevel 10 goto endgate
if errorlevel 9 goto utility
if errorlevel 8 goto allmsoft
if errorlevel 7 goto Dirmyc
if errorlevel 6 goto clang
if errorlevel 5 goto mini
if errorlevel 4 goto lastcfg
if errorlevel 3 goto Ramdrive
if errorlevel 2 goto best
if errorlevel 1 goto help
:Utility
cls
echo.
echo UTILITY OPEN MENU
echo -----------------------------------------------------------------
echo Selecting (C)opy opens a menu allowing copying of current
echo configuration to a MYC stored configuration file.
echo Selecting (E)dit opens a menu allowing editing the stored
echo MYC configuration files.
echo Selecting e(X)it returns you to Main MYC PICK MENU
echo -------------------------------------------------------------------
echo.
echo Will e(X) to Main Menu in 30 seconds or..
Choice /C:CEX /T:X,30 . SELECT-
if errorlevel 3 goto pickcf
if errorlevel 2 goto UtilEdit
if errorlevel 1 goto UtilCopy
goto endgate
:UtilCopy
Cls
echo.
echo The Copy options will COPY the current Autoexec.Bat to
echo (Pick).BAT ...and... COPY Config.Sys to (Pick).SYS.
echo.
set MYCFG=
echo PICK COPY OPTIONS
echo *-------------------------------------*
echo * V View current AutoExec.Bat *
echo * S See-View current Config.Sys *
echo * A Copy to (AllMSoft) *
echo * B Copy to (Best) *
echo * C Copy to (CLang) *
echo * R Copy to (Ram) drive-added *
echo * M Copy to (Mini)mum-No TSRS etc *
echo * Q Return to UTILITY OPEN MENU *
echo * X Exit--return to MYC Main Menu *
echo *-------------------------------------*
echo E(X)it in 30 seconds or...
choice /C:ABCRMVSQX /T:X,30 ...SELECT:
if errorlevel 9 goto pickcf
if errorlevel 8 goto utility
if errorlevel 7 goto SeeSYS
if errorlevel 6 goto VuBAT
if errorlevel 1 set MYCFG=allmsoft
if errorlevel 2 set MYCFG=best
if errorlevel 3 set MYCFG=Clang
if errorlevel 4 set MYCFG=Ram
if errorlevel 5 set MYCFG=mini
echo.
echo **** Press C to COPY C:\AUTOEXEC.BAT to C:\MYC\%MYCFG%.BAT ,
echo or Press N to NOT COPY
echo.
Choice /C:CN /T:C,20 ..PRESS..
if errorlevel 2 goto skipauto
if exist C:\AUTOEXEC.BAT COPY C:\AUTOEXEC.BAT C:\MYC\%MYCFG%.BAT
:skipauto
echo.
echo **** Press C to COPY C:\CONFIG.SYS to C:\MYC\%MYCFG%.SYS ,
echo or Press N to NOT COPY
echo.
Choice /C:CN /T:C,10 ..PRESS..
if errorlevel 2 goto skipsys
if exist C:\CONFIG.SYS COPY C:\CONFIG.SYS C:\MYC\%MYCFG%.SYS
:skipsys
SET MYCFG=
echo.
echo ***** To return to main menu,
pause
goto pickcf
goto endgate
:SeeSYS
CLS
if exist C:\CONFIG.SYS MORE<C:\CONFIG.SYS
echo ------------------------------------
echo ***** To return to PICK COPY OPTIONS,
pause
goto UTILCOPY
:VuBAT
CLS
if exist C:\AUTOEXEC.BAT MORE < C:\AUTOEXEC.BAT
echo -------------------------------------
echo ***** To return to PICK COPY OPTIONS,
pause
goto UTILCOPY
:UtilEdit
Cls
echo.
echo Selecting an Edit option from this menu will LOAD the stored
echo (Pick).BAT ...and.. (Pick).SYS into an editor.
echo.
echo PICK Edit OPTIONS of .BAT & .SYS Files
echo *-------------------------------------*
echo * A Edit (AllMSoft) *
echo * B Edit (Best) *
echo * C Edit (CLang) *
echo * R Edit to (Ram) drive-added *
echo * M Edit to (Mini)mum-No TSRS etc *
echo * Q Return to UTILITY OPEN MENU *
echo * X Exit--return to MYC Main Menu *
echo *-------------------------------------*
echo E(X)it in 20 seconds or...
choice /C:ABCRMQX /T:X,20 ...SELECT:
if errorlevel 7 goto Pickcf
if errorlevel 6 goto utility
if errorlevel 1 set MYCFG=allmsoft
if errorlevel 2 set MYCFG=best
if errorlevel 3 set MYCFG=Clang
if errorlevel 4 set MYCFG=Ram
if errorlevel 5 set MYCFG=mini
echo.
echo **** Press E to EDIT C:\MYC\%MYCFG%.BAT ,
echo or Press N to NOT EDIT
echo.
Choice /C:EN /T:E,20 ..PRESS..
if errorlevel 2 goto skedbat
if exist C:\MYC\%MYCFG%.BAT EDIT C:\MYC\%MYCFG%.BAT
:skedbat
echo.
echo **** Press E To EDIT C:\MYC\%MYCFG%.SYS ,
echo or Press N to NOT EDIT
echo.
Choice /C:EN /T:E,20 ...PRESS...
if errorlevel 2 goto skedsys
if exist C:\MYC\%MYCFG%.SYS EDIT C:\MYC\%MYCFG%.SYS
:skedsys
echo.
echo **** To return to main menu,
pause
set MYCFG=
goto pickcf
goto endgate
:dirmyc
cls
dir C:\myc /W /A-D
goto pickcf
:Clang
SET MYCFG=CLANG
SET MYTITLE=C-LANGUAGE
echo C-LANGUAGE CONFIGURATION > C:\myc\oneprior.txt
GOTO DOCOPY
goto endgate
:AllMSoft
SET MYCFG=ALLMSOFT
SET MYTITLE=ALL MICROSOFT
echo ALL MICROSOFT (No Opts) CONFIGURATION > C:\myc\oneprior.txt
GOTO DOCOPY
goto endgate
:Ramdrive
SET MYCFG=RAM
SET MYTITLE=RAMDRIVE
echo RAMDRIVE CONFIGURATION > C:\myc\oneprior.txt
GOTO DOCOPY
goto endgate
:best
SET MYCFG=BEST
SET MYTITLE=BEST (Optimized)
echo BEST CONFIGURATION > C:\myc\oneprior.txt
GOTO DOCOPY
goto endgate
:Mini
SET MYCFG=MINI
SET MYTITLE=MINIMUM
echo MINIMUM CONFIGURATION > C:\myc\oneprior.txt
GOTO DOCOPY
goto endgate
:Extra1
rem-------------------edit label and environmental names if amended----
SET MYCFG=EXTRA1
SET MYTITLE=EXTRA1TITLE
echo EXTRA1 CONFIGURATION > C:\myc\oneprior.txt
GOTO DOCOPY
goto endgate
:Extra2
rem-------------------edit label and environmental names if amended----
SET MYCFG=EXTRA2
SET MYTITLE=EXTRA2TITLE
echo EXTRA2 CONFIGURATION > C:\myc\oneprior.txt
GOTO DOCOPY
goto endgate
:Extra3
rem-------------------edit label and environmental names if amended----
SET MYCFG=EXTRA3
SET MYTITLE=EXTRA3TITLE
echo EXTRA3 CONFIGURATION > C:\myc\oneprior.txt
GOTO DOCOPY
goto endgate
:Lastcfg
:message
cls
echo In 5 seconds, system will
echo be configured to
type c:\myc\twoprior.txt
echo -- UNLESS you press N NOW!"
echo.
choice /C:.N /N /T:.,05
if errorlevel 2 goto pickcf
rem -------------rem goto message command after testing-------
rem goto message
echo .....Please wait as files are saved & copied..Then select reboot option.
echo ------------------------------------------------------------------------
if exist c:\myc\twoprior.txt copy c:\myc\twoprior.txt c:\myc\prior.tmp
if exist c:\myc\oneprior.txt copy c:\myc\oneprior.txt c:\myc\twoprior.txt
if exist c:\myc\prior.tmp copy c:\myc\prior.tmp c:\myc\oneprior.txt
if not exist C:\myc\nul md C:\myc
if exist C:\myc\autoexec.LST copy C:\myc\autoexec.LST C:\myc\autoexec.TMP
if exist C:\myc\config.LST copy C:\myc\config.LST C:\myc\Config.TMP
copy C:\Autoexec.BAT C:\myc\AUTOEXEC.LST
copy C:\Config.SYS C:\myc\Config.LST
if exist C:\myc\autoexec.TMP copy C:\myc\autoexec.TMP C:\autoexec.BAT
if exist C:\myc\config.SYS copy C:\myc\config.SYS C:\Config.SYS
goto bootopts
goto endgate
:DOCOPY
cls
echo System will be configured to
echo %MYTITLE% mode in 10 seconds
echo -- UNLESS you press N NOW!"
echo.
choice /C:.N /N /T:.,10
if errorlevel 2 goto pickcf
echo -----------------------------------------------------------------------
echo ....... Please wait for file copying and then reboot options ..........
echo -----------------------------------------------------------------------
ECHO %MYCFG%
COPY C:\AUTOEXEC.BAT C:\MYC\MYCBAT.SAV
COPY C:\CONFIG.SYS C:\MYC\MYCSYS.SAV
IF NOT EXIST C:\MYC\%MYCFG%.BAT ECHO %MYCFG%.BAT DOES NOT EXIST
IF NOT EXIST C:\MYC\%MYCFG%.SYS ECHO %MYCFG%.SYS DOES NOT EXIST
IF EXIST C:\MYC\%MYCFG%.BAT COPY C:\MYC\%MYCFG%.BAT C:\AUTOEXEC.BAT
IF EXIST C:\MYC\%MYCFG%.SYS COPY C:\MYC\%MYCFG%.SYS C:\CONFIG.SYS
GOTO BOOTOPTS
:bootopts
echo.
echo SELECT: ------------------------------------------------
echo (W)armboot NOTE: Configuration has been changed, whether or
echo (C)oldboot not you do re-boot; but, changes will NOT take
echo e(X)it effect until system is re-booted or turned off
echo and restarted.
echo ------------------------------------------------
ECHO.
choice /C:WCX /T:C,30 ..SELECT..
if errorlevel 3 goto endgate
if errorlevel 2 Coldboot.Com
if errorlevel 1 Warmboot.Com
:endgate